VBA Deep Clone Dictionary

' Compare mode for cloning dictionary object
' See CloneDictionary function
Public Enum eCompareMethod2
    ecmBinaryCompare = 0
    ecmTextCompare = 1
    ecmDatabaseCompare = 2
    ' Added this to use original compare method
    ecmSourceMethod = 3
End Enum


'---------------------------------------------------------------------------------------
' Procedure : CloneDictionary
' Author    : Adam Waller
' Date      : 3/30/2021
' Purpose   : Recursive function to deep-clone a dictionary object, including nested
'           : dictionaries.
'           : NOTE: All other object types are cloned as a reference to the same object
'           : referenced by the original dictionary, not a new object.
'---------------------------------------------------------------------------------------
'
Public Function CloneDictionary(dSource As Dictionary, _
    Optional Compare As eCompareMethod2 = ecmSourceMethod) As Dictionary

    Dim dNew As Dictionary
    Dim dChild As Dictionary
    Dim varKey As Variant

    ' No object returned if source is nothing
    If dSource Is Nothing Then Exit Function

    ' Create new dictionary object and set compare mode
    Set dNew = New Dictionary
    If Compare = ecmSourceMethod Then
        ' Use the same compare mode as the original dictionary.
        dNew.CompareMode = dSource.CompareMode
    Else
        dNew.CompareMode = Compare
    End If
    
    ' Loop through keys
    For Each varKey In dSource.Keys
        If TypeOf varKey Is Dictionary Then
            ' Call this function recursively to add nested dictionary
            Set dChild = varKey
            dNew.Add varKey, CloneDictionary(dChild, Compare)
        Else
            ' Add key to dictionary
            dNew.Add varKey, dSource(varKey)
        End If
    Next varKey
    
    ' Return new dictionary
    Set CloneDictionary = dNew
    
End Function

Source: stackoverflow.com

Similar codes

0 vote265 views1 answer
Vbnet check if string is only letters
VBA
0 vote230 views1 answer
Faire appel à la mise en forme conditionnelle vba excel
VBA
0 vote245 views1 answer
Vbnet line chart showing extra space
VBA
0 vote244 views1 answer
Not allow form to be resized
VBA
0 vote246 views1 answer
Reset border color textbox vba
VBA
2 votes225 views1 answer
Vba split string
VBA
0 vote245 views1 answer
Vba dropdown event
VBA
-1 vote230 views1 answer
Vba code to add new column in table
VBA
0 vote246 views1 answer
Vbnet convert charatcer to binary
VBA
0 vote255 views1 answer
Vba clear collection
VBA