/Java/Batch file to switch between java version

Batch file to switch between java version

@echo off
echo.

IF "%1" == ""       GOTO NoParams
IF "%1" == "8"      GOTO J8
IF "%1" == "11"     GOTO J11
IF "%1" == "latest" GOTO latest

IF "%1" == "-h"         GOTO help
IF "%1" == "--help"     GOTO help

:NoParams
    echo Enter Java version
    GOTO options
    
:help
    echo Usage: javaVer [java version]
    GOTO options

:: available java versions
:options
    echo options: 8, 11, latest.
    GOTO exit

:: java 8
:J8
    set JAVA_HOME=C:\Program Files\Java\jdk8u282-b08
    GOTO activate

:: java 11
:J11
    set JAVA_HOME=C:\Program Files\Java\jdk-11.0.10+9
    GOTO activate

:: latest java version
:latest
    set JAVA_HOME=C:\Program Files\Java\jdk-15.0.2+7
    GOTO activate

:: activates the selected java version
:activate
    set Path=%JAVA_HOME%\bin;%Path%
    echo Java %1 activated.
    GOTO exit

:: prints java version
:exit
    echo.
    echo Current Java version:
    java -version

Source: stackoverflow.com

Similar codes

-1 vote168 views1 answer
Spring boot show sql
Java Spring
2 votes169 views1 answer
Full screen in jframe
Java
0 vote127 views1 answer
Jasypt-spring-boot
Java
0 vote90 views1 answer
What is final class
Java
0 vote120 views1 answer
Concurrentskiplistset infinite loop in jdk
Java
2 votes135 views2 answers
Android settextcolor programmatically
Java
0 vote133 views1 answer
UTC in Java
Java
4 votes138 views2 answers
Java reentrantlock
Java
6 votes130 views6 answers
Java do while loop example
Java
1 vote152 views2 answers
Java swing dialog box
Java